SmartCapture forms provide a quick, user-friendly way to create simple forms and use them in Salesforce Marketing Cloud journeys, but they are not very versatile and often can create more problems than they actually solve.
In this tutorial, you will learn how to create a form using HTML and AMPscript and include functions that will let you quickly push the collected data into your instance of Sales/Service Cloud.
Create an HTML form
First, let’s create a very simple HTML form. If you’ve never created forms in HTML, you can start with reading this short overview on w3schools. The form action method attribute specifies how to send form-data. In this case, we are using post, which appends form-data inside the body of the HTTP request (data is not shown is in URL).
| <table style="padding: 20px;"><tr><td> | |
| <h2>Please fill in the form:</h2> | |
| <form action="%%=RequestParameter('PAGEURL')=%%" method="post"> | |
| <label>First name: </label><input type="text" name="firstname" required=""><br> | |
| <label>Last name: </label><input type="text" name="lastname" required=""><br> | |
| <label>Company: </label><input type="text" name="company" required=""><br> | |
| <label>Email: </label><input type="text" name="email" required=""><br> | |
| <input name="submitted" type="hidden" value="true"><br> | |
| <input type="submit" value="Submit"> | |
| </form> | |
| </td></tr></table> |
The RequestParameter('PAGEURL') function reloads the page when the form is submitted, posting the form parameters back to the same page, which are then retrieved by the RequestParameter() AMPscript functions. The form has a hidden submitted field. If this value is set to true, which it would after submitting the form, it will trigger the evaluation of the AMPscript functions. Here is a simplified diagram to help you understand this concept:
That’s why in the first step we check if the form has already been submitted or not. Let’s add the AMPscript functions to the form now.
Create form logic using AMPscript
Let’s start simple with creating a Sales Cloud Lead using the data collected in the form. The AMPscript needs to be placed at the top, as it should be evaluated upon form submission and prevent the form fields from being displayed after it’s been submitted. In the below script, we use the CreateSalesforceObject function to create a new Lead:
| %%[ | |
| IF RequestParameter("submitted") == true THEN | |
| /* create a new lead */ | |
| SET @leadId = CreateSalesforceObject( | |
| "Lead", 4, | |
| "FirstName", RequestParameter("firstname"), | |
| "LastName", RequestParameter("lastname"), | |
| "Company", RequestParameter("company"), | |
| "Email", RequestParameter("email") | |
| ) | |
| ]%% | |
| <h2>Thank you for submitting the form.</h2> | |
| %%[ ELSE ]%% | |
| <table style="padding: 20px;"><tr><td> | |
| <h2>Please fill in the form:</h2> | |
| <form action="%%=RequestParameter('PAGEURL')=%%" method="post"> | |
| <label>First name: </label><input type="text" name="firstname" required=""><br> | |
| <label>Last name: </label><input type="text" name="lastname" required=""><br> | |
| <label>Company: </label><input type="text" name="company" required=""><br> | |
| <label>Email: </label><input type="text" name="email" required=""><br> | |
| <input name="submitted" type="hidden" value="true"><br> | |
| <input type="submit" value="Submit"> | |
| </form> | |
| </td></tr></table> | |
| %%[ ENDIF ]%% |
We can extend the logic a bit by checking first if the Lead with the given email address already exists in Sales Cloud, and if yes – updating their data, or if not – creating a new Lead:
| %%[ | |
| IF RequestParameter("submitted") == true THEN | |
| /* check if lead already exists */ | |
| SET @subscriberRows = RetrieveSalesforceObjects( | |
| "Lead", | |
| "Id,Email", | |
| "Email", "=", RequestParameter("email") | |
| ) | |
| /* get lead id if lead exists */ | |
| IF RowCount(@subscriberRows) > 0 THEN | |
| SET @leadId = Field(Row(@subscriberRows, 1), "Id") | |
| /* update existing lead */ | |
| SET @updateRecord = UpdateSingleSalesforceObject( | |
| "Lead", @leadId, | |
| "FirstName", RequestParameter("firstname"), | |
| "LastName", RequestParameter("lastname"), | |
| "Company", RequestParameter("company") | |
| ) | |
| ELSE | |
| /* create a new lead */ | |
| SET @leadId = CreateSalesforceObject( | |
| "Lead", 4, | |
| "FirstName", RequestParameter("firstname"), | |
| "LastName", RequestParameter("lastname"), | |
| "Company", RequestParameter("company"), | |
| "Email", RequestParameter("email") | |
| ) | |
| ENDIF | |
| ]%% | |
| <h2>Thank you for submitting the form.</h2> | |
| %%[ ELSE ]%% | |
| <table style="padding: 20px;"><tr><td> | |
| <h2>Please fill in the form:</h2> | |
| <form action="%%=RequestParameter('PAGEURL')=%%" method="post"> | |
| <label>First name: </label><input type="text" name="firstname" required=""><br> | |
| <label>Last name: </label><input type="text" name="lastname" required=""><br> | |
| <label>Company: </label><input type="text" name="company" required=""><br> | |
| <label>Email: </label><input type="text" name="email" required=""><br> | |
| <input name="submitted" type="hidden" value="true"><br> | |
| <input type="submit" value="Submit"> | |
| </form> | |
| </td></tr></table> | |
| %%[ ENDIF ]%% |
Let’s now add the Lead to a Campaign in Sales Cloud. You will need to hardcode the Campaign Id into the script. Note that you cannot add the same Lead to a campaign twice, so if the Lead has already been added to the campaign, you will get an error. Let’s add creating a new Campaign Member to the script:
| %%[ | |
| IF RequestParameter("submitted") == true THEN | |
| /* check if lead already exists */ | |
| SET @subscriberRows = RetrieveSalesforceObjects( | |
| "Lead", | |
| "Id,Email", | |
| "Email", "=", RequestParameter("email") | |
| ) | |
| /* get lead id if lead exists */ | |
| IF RowCount(@subscriberRows) > 0 THEN | |
| SET @leadId = Field(Row(@subscriberRows, 1), "Id") | |
| /* update existing lead */ | |
| SET @updateRecord = UpdateSingleSalesforceObject( | |
| "Lead", @leadId, | |
| "FirstName", RequestParameter("firstname"), | |
| "LastName", RequestParameter("lastname"), | |
| "Company", RequestParameter("company") | |
| ) | |
| ELSE | |
| /* create a new lead */ | |
| SET @leadId = CreateSalesforceObject( | |
| "Lead", 4, | |
| "FirstName", RequestParameter("firstname"), | |
| "LastName", RequestParameter("lastname"), | |
| "Company", RequestParameter("company"), | |
| "Email", RequestParameter("email") | |
| ) | |
| ENDIF | |
| /* add lead to a campaign*/ | |
| SET @CampaignMember = CreateSalesforceObject("CampaignMember", 3, | |
| "CampaignId", "7011t0000009Cl1", | |
| "LeadId", @leadId, | |
| "Status", "Sent" | |
| ) | |
| ]%% | |
| <h2>Thank you for submitting the form.</h2> | |
| %%[ ELSE ]%% | |
| <table style="padding: 20px;"><tr><td> | |
| <h2>Please fill in the form:</h2> | |
| <form action="%%=RequestParameter('PAGEURL')=%%" method="post"> | |
| <label>First name: </label><input type="text" name="firstname" required=""><br> | |
| <label>Last name: </label><input type="text" name="lastname" required=""><br> | |
| <label>Company: </label><input type="text" name="company" required=""><br> | |
| <label>Email: </label><input type="text" name="email" required=""><br> | |
| <input name="submitted" type="hidden" value="true"><br> | |
| <input type="submit" value="Submit"> | |
| </form> | |
| </td></tr></table> | |
| %%[ ENDIF ]%% |
And now, let’s put the icing on the cake and send a confirmation email to the Lead. You will need to create a Triggered Send beforehand – if you’re not sure how, read my blog post: Send a triggered email using AMPscript. We will hardcode the Triggered Send external key as @ts_extkey, pass the Lead ID and Email Address to a new Subscriber object and invoke creation of a new Triggered Send object:
| %%[ | |
| IF RequestParameter("submitted") == true THEN | |
| /* check if lead already exists */ | |
| SET @subscriberRows = RetrieveSalesforceObjects( | |
| "Lead", | |
| "Id,Email", | |
| "Email", "=", RequestParameter("email") | |
| ) | |
| /* get lead id if lead exists */ | |
| IF RowCount(@subscriberRows) > 0 THEN | |
| SET @leadId = Field(Row(@subscriberRows, 1), "Id") | |
| /* update existing lead */ | |
| SET @updateRecord = UpdateSingleSalesforceObject( | |
| "Lead", @leadId, | |
| "FirstName", RequestParameter("firstname"), | |
| "LastName", RequestParameter("lastname"), | |
| "Company", RequestParameter("company") | |
| ) | |
| ELSE | |
| /* create a new lead */ | |
| SET @leadId = CreateSalesforceObject( | |
| "Lead", 4, | |
| "FirstName", RequestParameter("firstname"), | |
| "LastName", RequestParameter("lastname"), | |
| "Company", RequestParameter("company"), | |
| "Email", RequestParameter("email") | |
| ) | |
| ENDIF | |
| /* add lead to a campaign*/ | |
| SET @CampaignMember = CreateSalesforceObject("CampaignMember", 3, | |
| "CampaignId", "7011t0000009Cl1", | |
| "LeadId", @leadId, | |
| "Status", "Sent" | |
| ) | |
| /* send a confirmation email */ | |
| SET @ts = CreateObject("TriggeredSend") | |
| SET @tsDef = CreateObject("TriggeredSendDefinition") | |
| SET @ts_extkey = "43099" | |
| SET @ts_email = RequestParameter("email") | |
| SetObjectProperty(@tsDef, "CustomerKey", @ts_extkey) | |
| SetObjectProperty(@ts, "TriggeredSendDefinition", @tsDef) | |
| SET @ts_sub = CreateObject("Subscriber") | |
| SetObjectProperty(@ts_sub, "EmailAddress", @ts_email) | |
| SetObjectProperty(@ts_sub, "SubscriberKey", @leadId) | |
| AddObjectArrayItem(@ts, "Subscribers", @ts_sub) | |
| SET @ts_statusCode = InvokeCreate(@ts, @ts_statusMsg, @errorCode) | |
| ]%% | |
| <h2>Thank you for submitting the form, you will get a confirmation email shortly.</h2> | |
| %%[ ELSE ]%% | |
| <table style="padding: 20px;"><tr><td> | |
| <h2>Please fill in the form:</h2> | |
| <form action="%%=RequestParameter('PAGEURL')=%%" method="post"> | |
| <label>First name: </label><input type="text" name="firstname" required=""><br> | |
| <label>Last name: </label><input type="text" name="lastname" required=""><br> | |
| <label>Company: </label><input type="text" name="company" required=""><br> | |
| <label>Email: </label><input type="text" name="email" required=""><br> | |
| <input name="submitted" type="hidden" value="true"><br> | |
| <input type="submit" value="Submit"> | |
| </form> | |
| </td></tr></table> | |
| %%[ ENDIF ]%% |
You now have a fully functional lead capture form integrated with Sales Cloud!
If you’d like to see this in action, fill in this example form that I created to receive a confirmation email:
https://pub.s10.exacttarget.com/bhu3kciqhjk.
sfmarketing.cloud 
Hello, I’m having issues connecting this code to an email link from MC. I use the button and link the corresponding landing page. I also changes the email to subkey. Do you have resources on this already or can provide assistance?
LikeLike
Hi Vinetia – the way you did it sounds correct. You can use the button and choose the CloudPage from the drop-down, or you can create a link yourself using the CloudPagesURL AMPscript function. After you’ve done that, you need to preview the email against an actual subscriber to check if the links is working: https://help.salesforce.com/articleView?id=mc_es_perform_subscriber_preview_test_send.htm&type=5
LikeLike
Thanks for your reply! The issue I am facing is that the “preview and test” generates the subscriber page and launches the cloud page accurately but does not update the lead but instead creates a new lead. On the other side of the coin, I send a real test email to my inbox as an subscriber and I get and 500 error when clicking the button to the cloud page.
LikeLike
Hi Zuzanna,
First of all, thank you for your awesome blog. I have one question: In the above example, we are using the static id of the campaign to add the campaign member. Is there any way to make the campaign id dynamic? what is the best way to add the campaign member in the campaign?
/* add lead to a campaign*/
SET @CampaignMember = CreateSalesforceObject(“CampaignMember”, 3,
“CampaignId”, “7011t0000009Cl1”,
“LeadId”, @leadId,
“Status”, “Sent”
)
Thanks,
Dharmendra Singh
LikeLike
Hi Dharmendra – form your email I understand that you have a problem with setting checkbox values. Let me quote my other article here to help you out:
“For each of the checkboxes, I have added the following in-line IF function: Iif(RequestParameter(“newsletter”) == “on”, “true”, “false”). That is because the checkbox passed from the HTML form will have a value of either on or off, while to pass it to Sales/Service Cloud, we need to convert it to a boolean value of true or false.”
You can access the full article here: https://sfmarketing.cloud/2020/01/14/custom-profile-and-subscription-center-integrated-with-sales-service-cloud/
Hope this helps!
Zuzanna
LikeLike
For the dynamic Campaign part, you would have to create a @CampaignID variable and set the Campaign ID dynamically based on the rules you will have in place. It could be, for example, a list of checkboxes for different Campaigns that the subscriber wants to subscribe to, and then based on what they checked, you could dynamically add them as a Campaign Member to those Campaigns.
LikeLike
Thanks for your quick response Zuzanna. Please can you send me some dummy code /reference links to make the Campaign ID dynamically?
LikeLike
Just found your blog. Really great stuff. I am working on this exact thing, and even thought I did it slightly different, I’m using pretty much the same approach. My question is about scrubbing the form data? Does AMPscript script have any kind of “strip tags” function, or maybe I should try using SSJS? I’m also worried about cross-domain funny business (bots). Any thoughts?
LikeLike
Hi Troy – there’s a couple of options here. First, the one which is most secure, but takes a little bit of effort to implement, reCaptcha: https://ampscript.xyz/how-tos/how-to-implement-google-recaptcha-on-marketing-cloud-forms/.
Second option, less secure, but much easier to implement, would be including a “honeypot” field on the form. You can include a field on your form, which is hidden and by default to a certain value. The idea behind it is that no one who is a “real human” will be able to change its value, so you would treat all submissions with the honeypot field set to the default value as valid. If the value is changed, you would not process this particular submission, assuming that it was filled in by a bot.
LikeLike
Hi Zuzanna,
Thanks for your awesome blog. I have created the lead through this form and the lead is adding in the campaign. But if that lead is already added we are getting the error. Please can you let me know how we can avoid this?
LikeLike
Sure Bhav – you can add an extra condition in the script, right before adding the lead to the campaign to check if the Lead Id already exists as a CampaignMember. You can do it by checking the CampaignMember object using something like:
if RowCount(RetrieveSalesforceObjects(“CampaignMember”,”Id,LeadId”,”LeadId”, “=”, _subscriberKey )) == 0 then
/* add new Campaign Member */
….
endif
LikeLike
Hi Zuzanna,
thanks for quick response. I am still getting the 500 error when i try to add same lead to campaign. Follwing the code which I am using:
%%[
IF RequestParameter(“submitted”) == true THEN
/* check if lead already exists */
SET @subscriberRows = RetrieveSalesforceObjects(
“Lead”,
“Id,Email”,
“Email”, “=”, RequestParameter(“email”)
)
/* get lead id if lead exists */
IF RowCount(@subscriberRows) > 0 THEN
SET @leadId = Field(Row(@subscriberRows, 1), “Id”)
/* update existing lead */
SET @updateRecord = UpdateSingleSalesforceObject(
“Lead”, @leadId,
“FirstName”, RequestParameter(“firstname”),
“LastName”, RequestParameter(“lastname”),
“Company”, RequestParameter(“company”)
)
ELSE
/* create a new lead */
SET @leadId = CreateSalesforceObject(
“Lead”, 4,
“FirstName”, RequestParameter(“firstname”),
“LastName”, RequestParameter(“lastname”),
“Company”, RequestParameter(“company”),
“Email”, RequestParameter(“email”)
)
ENDIF
/* add lead to a campaign*/
if RowCount(RetrieveSalesforceObjects(
“CampaignMember”,
“Id,LeadId”,
“LeadId”, “=”, _subscriberKey )) == 0 then
SET @CampaignMember = CreateSalesforceObject(“CampaignMember”, 3,
“CampaignId”, “7010r000000DiHB”,
“LeadId”, @leadId,
“Status”, “Sent”
)
endif
]%%
Thank you for submitting the form .
%%[ ELSE ]%%
Please let me know what i am missing here.
LikeLike
Try replacing _subscriberkey with @leadid
LikeLike
Hi Zuzanna,
Is it possible to add one lead with multiple campaigns through AMpscript? I am using the following script before adding the campaign member:
if RowCount(RetrieveSalesforceObjects(“CampaignMember”,”Id,LeadId”,”LeadId”, “=”, @leadid )) == 0 then
/* add new Campaign Member */
….
endif
But in this case, it skips that lead if it’s attached any of the campaigns in salesforce. Through the above check, only one lead can be added to only one campaign. It is working on the new records but not working on the update case?
Please can you let me know how can I achieve this?
LikeLike
Hi Zuzanna,
Brilliantly explained article.Thank you for providing all the details and codes. i used the Pardot and created the form handler in the Pardot. Now we moved in the marketing cloud and want to implement a similar kind of functionality in the marketing cloud but not found any link related to formhandler. Please can you let me know how I can achieve this in marketing cloud?
Thanks in advance.
LikeLike
Hi Bhawani, the code provided is a form and a form handler in one page. If needed, you can post form data into another page and create the handler there – just split the code into two parts: form separately and the part that processes the data would be the second part.
LikeLike
Hi Zuzanna,
A very big thank you for posting this blog. it is so much information and now it seems too easy to integrate an HTML form with Salesforce.
However, my question is that can we create a lead in the sales cloud using the marketing cloud’s smart capture form with the help of AMP Script. if yes then please guide me on how to achieve the same.
I really want to know if smart capture supports AMP Script to create an object in salesforce.
LikeLike
Hi Zuzanna,
I got an idea/overview from above article and it helped me in implementing similar requirement,
However – our default lead record type for the “System Admin” profile (which the MC Integration user sits in) sitting the created data in default recordtypeid, but i need to sit this data in other recordtypeid.
Below is code I am using explicitly mentioning in the recordtypeid i want my lead object to sit in – but still its not working did i missed anything here ?
Platform.Load(“Core”,”1″);
try{
%%[
if RequestParameter(“submitted”) == true then
var @createLead,@recordTypeId
set @recordTypeId =”0123g000000PEsbAAG”
set @createLead = CreateSalesforceObject(
“Lead”, 7,
“FirstName”, RequestParameter(“firstname”),
“LastName”, RequestParameter(“lastname”),
“Company”, RequestParameter(“company”),
“Email”, RequestParameter(“email”),
“Phone”, RequestParameter(“Phone Number”),
“Insurance_Carrier__c”, RequestParameter(“Insurance_Carrier”),
“LeadType__c”, RequestParameter(“Lead_Types”),
“RecordTypeId”,@recordTypeId
)
Thanks in advance!!
LikeLike
Thank you for this tutorial Zuzanna.
I just wanted to help others- I was receiving a 500 error when entering an email that already existed as a lead. After some trouble shooting it appears this error was from the campaign ID section of the code as it was trying to add a campaign ID for the subscriber which already had the campaign ID associated. I simply moved creating the Campaign ID into if statement for creating a new lead.
This should serve for my purpose. As we don’t have many existing leads so not having them associated to this campaign isn’t the end of the world.
Again thank you Zuzanna for your guidance on this topic and many others.
LikeLike
hey, I tried your code but the leads are not updating. do you know the reason why? I really need this thing to work! Thanks in advance
LikeLike
Hi Zuzanna, thank you for publishing this solution.
It is not clear for me if PAGEURL parameter has to be set beforehand or how else the function RequestParameter(‘PAGEURL’) can work? Thanks!
LikeLike
It’s a personalization string, no need to do anything! https://ampscript.guide/system-strings/
LikeLike
Hi Zuzanna,
Thank you so much for your awesome blog, Please see my below questions.
1) I have tried the above code and getting “500 internal error” only when the lead exists and trying to update his details, Even though I am getting 500 error in this case lead is getting successfully updated in the campaign list.
2) By keeping “try” “catch” block in script I can able to avoid 500 internal server error. (Is there anything that I can look in to ? )
3) Also I am getting “Thank you for submitting the form.” message only when the new lead is getting added to the campaign list not when lead is updated.
4)Also I wanted to check the below scenarios from contact and lead as well, please check the below code which I am using currently and update it accordingly.
It would be really helpful if you can share the code.
-> check by email if contact exists already
If so, add contact to campaign list
-> if not already a contact, check if already a lead
If so, add current lead record to Campaign
-> If not, create new Lead using form details
Add new Lead to the campaign
———————————————————————-
Platform.Load(“Core”,”1.1.1″);
try{
%%[
IF RequestParameter(“submitted”) == true THEN
/* check if lead already exists */
SET @subscriberRows = RetrieveSalesforceObjects(
“Lead”,
“Id,Email”,
“Email”, “=”, RequestParameter(“email”)
)
/* get lead id if lead exists */
IF RowCount(@subscriberRows) > 0 THEN
SET @leadId = Field(Row(@subscriberRows, 1), “Id”)
/* update existing lead */
SET @updateRecord = UpdateSingleSalesforceObject(
“Lead”, @leadId,
“FirstName”, RequestParameter(“firstname”),
“LastName”, RequestParameter(“lastname”),
“Company”, RequestParameter(“company”)
)
ELSE
/* create a new lead */
SET @leadId = CreateSalesforceObject(
“Lead”, 4,
“FirstName”, RequestParameter(“firstname”),
“LastName”, RequestParameter(“lastname”),
“Company”, RequestParameter(“company”),
“Email”, RequestParameter(“email”)
)
ENDIF
/* add lead to a campaign*/
SET @CampaignMember = CreateSalesforceObject(“CampaignMember”, 3,
“CampaignId”, “1234567890”,
“LeadId”, @leadId,
“Status”, “Sent”
)
]%%
Thank you for submitting the form.
%%[ ELSE ]%%
Please fill in the form:
First name:
Last name:
Company:
Email:
%%[ ENDIF ]%%
Platform.Load(“Core”,”1.1.1″);
}
catch(e)
{
}
LikeLike
Hi, please take this to Salesforce Stack Exchange
LikeLike
hi, i´m trying to obtain some data from a DE and redirect this data to other cloud page but i´m getting the error “Blocked form submission to ” because the form’s frame is sandboxed and the ‘allow-forms’ permission is not set.” i´ve tried with the html iframe and dansbox=”allow forms” but the error remains, i´d appreciate any help, thanks
%%[
var @cc, @rows, @row, @AccountId, @MemberId
if RequestParameter(“submitted”) == true then
set @cc = RequestParameter(‘cc’)
set @rows = LookupRows(“DE_ViveTerpel_BigPromo”, “NumeroIdentificacion”, @cc)
if RowCount(@rows) > 0 then
set @row = Row(@rows, 1)
set @AccountId = Field(@row, “AccountID”)
set @MemberId = Field(@row, “MemberId”)
else
set @AccountId = “”
set @MemberId = “”
endif
else
set @AccountId = “”
set @MemberId = “”
endif
]%%
%%[ if RequestParameter(“submitted”) == true then ]%%
Thank you for submitting your details.
%%[ else ]%%
Register
CC:
Buscar
%%[ endif ]%%
LikeLike
Hi Zuzanna,
Thank you so much for your articles, they are amazing. I’ve used the code as above and just updated my attribute names.
The landing page loads without issues to start with but upon submission, I’m getting a 500 error instead of the confirmation, I’m not sure what is wrong.
My code is this:
%%[
IF RequestParameter(“submitted”) == true THEN
/* check if lead already exists */
SET @subscriberRows = RetrieveSalesforceObjects(
“Lead”,
“Id,Email”,
“Email”, “=”, RequestParameter(“EmailAddress”)
)
/* get lead id if lead exists */
IF RowCount(@subscriberRows) > 0 THEN
SET @leadId = Field(Row(@subscriberRows, 1), “Id”)
/* update existing lead */
SET @updateRecord = UpdateSingleSalesforceObject(
“Lead”, @leadId,
“FirstName”, RequestParameter(“FirstName”),
“LastName”, RequestParameter(“LastName”),
“Phone”, RequestParameter(“Mobile”)
)
ELSE
/* create a new lead */
SET @leadId = CreateSalesforceObject(
“Lead”, 4,
“FirstName”, RequestParameter(“FirstName”),
“LastName”, RequestParameter(“LastName”),
“Email”, RequestParameter(“EmailAddress”),
“Phone”, RequestParameter(“Mobile”)
)
ENDIF
/* add lead to a campaign*/
SET @CampaignMember = CreateSalesforceObject(“CampaignMember”, 3,
“CampaignId”, “7012w000000AHTNAA4”,
“LeadId”, @leadId,
“Status”, “Sent”
)
/* send a confirmation email */
SET @ts = CreateObject(“TriggeredSend”)
SET @tsDef = CreateObject(“TriggeredSendDefinition”)
SET @ts_extkey = “184751”
SET @ts_email = RequestParameter(“EmailAddress”)
SET @ts_subkey = _subscriberkey
SetObjectProperty(@tsDef, “CustomerKey”, @ts_extkey)
SetObjectProperty(@ts, “TriggeredSendDefinition”, @tsDef)
SET @ts_sub = CreateObject(“Subscriber”)
SetObjectProperty(@ts_sub, “EmailAddress”, @ts_email)
SetObjectProperty(@ts_sub, “SubscriberKey”, @leadId)
AddObjectArrayItem(@ts, “Subscribers”, @ts_sub)
SET @ts_statusCode = InvokeCreate(@ts, @ts_statusMsg, @errorCode)
]%% Vielen Dank. Du wirst in Kürze eine Email erhalten.
%%[ ELSE ]%%
<table style=”padding: 20px; text-align: center;”>
<tr>
<td>
<form action=”%%=RequestParameter(‘PAGEURL’)=%%” method=”post”>
<label style=”color: #8B6212;”>Vorname: </label><br><input type=”text” name=”FirstName” required=”” style=”width: 200px; padding: 10px; margin: 5px; border: 1px solid #8B6212; background: #ffffff;”><br>
<label style=”color: #8B6212;”>Nachname: </label><br><input type=”text” name=”LastName” required=”” style=”width: 200px; padding: 10px; margin: 5px; border: 1px solid #8B6212; background: #ffffff;”><br>
<label style=”color: #8B6212;”>Email: </label><br><input type=”text” name=”EmailAddress” required=”” style=”width: 200px; padding: 10px; margin: 5px; border: 1px solid #8B6212; background: #ffffff;”><br>
<label style=”color: #8B6212;”>Mobilfunknummer: </label><br><input type=”text” name=”Mobile” required=”” style=”width: 200px; padding: 10px; margin: 5px; border: 1px solid #8B6212; background: #ffffff;”><br>
<input name=”submitted” type=”hidden” value=”true”><br>
<input type=”submit” value=”Newsletter abonnieren” style=”background-color: #8B6212; color: #ffffff; padding: 10px 20px; border: none; cursor: pointer;”>
</form>
</td>
</tr>
</table>
%%[ ENDIF ]%%
LikeLike
Hi Claudia, please post this to Salesforce Stack Exchange with a marketing-cloud tag, and either I or other community members will give this a look, thanks!
LikeLike